FM / demos

/opt/imh/python3.13/lib/tk8.6/demos

Name	Size	Mode	Actions
images/	-	0755	rm
anilabel.tcl	6670	0644	edit dl rm
aniwave.tcl	3494	0644	edit dl rm
arrow.tcl	8110	0644	edit dl rm
bind.tcl	3078	0644	edit dl rm
bitmap.tcl	1411	0644	edit dl rm
browse	1758	0755	edit dl rm
button.tcl	1504	0644	edit dl rm
check.tcl	2310	0644	edit dl rm
clrpick.tcl	1431	0644	edit dl rm
colors.tcl	5002	0644	edit dl rm
combo.tcl	1963	0644	edit dl rm
cscroll.tcl	5041	0644	edit dl rm
ctext.tcl	6205	0644	edit dl rm
dialog1.tcl	974	0644	edit dl rm
dialog2.tcl	828	0644	edit dl rm
en.msg	3867	0644	edit dl rm
entry1.tcl	1401	0644	edit dl rm
entry2.tcl	2106	0644	edit dl rm
entry3.tcl	6102	0644	edit dl rm
filebox.tcl	2351	0644	edit dl rm
floor.tcl	81000	0644	edit dl rm
fontchoose.tcl	1710	0644	edit dl rm
form.tcl	1046	0644	edit dl rm
goldberg.tcl	56666	0644	edit dl rm
hello	512	0755	edit dl rm
hscale.tcl	1497	0644	edit dl rm
icon.tcl	2063	0644	edit dl rm
image1.tcl	1002	0644	edit dl rm
image2.tcl	3359	0644	edit dl rm
items.tcl	10495	0644	edit dl rm
ixset	8075	0755	edit dl rm
knightstour.tcl	9123	0644	edit dl rm
label.tcl	1379	0644	edit dl rm
labelframe.tcl	1847	0644	edit dl rm
license.terms	2267	0644	edit dl rm
mclist.tcl	4357	0644	edit dl rm
menu.tcl	7292	0644	edit dl rm
menubu.tcl	4255	0644	edit dl rm
msgbox.tcl	1998	0644	edit dl rm
nl.msg	6750	0644	edit dl rm
paned1.tcl	1130	0644	edit dl rm
paned2.tcl	2244	0644	edit dl rm
pendulum.tcl	7649	0644	edit dl rm
plot.tcl	2757	0644	edit dl rm
puzzle.tcl	2603	0644	edit dl rm
radio.tcl	2752	0644	edit dl rm
README	2082	0644	edit dl rm
rmt	5319	0755	edit dl rm
rolodex	8303	0755	edit dl rm
ruler.tcl	5333	0644	edit dl rm
sayings.tcl	2273	0644	edit dl rm
search.tcl	4403	0644	edit dl rm
spin.tcl	1820	0644	edit dl rm
states.tcl	2048	0644	edit dl rm
style.tcl	6943	0644	edit dl rm
tclIndex	5298	0644	edit dl rm
tcolor	11253	0755	edit dl rm
text.tcl	4291	0644	edit dl rm
textpeer.tcl	2188	0644	edit dl rm
timer	1095	0755	edit dl rm
toolbar.tcl	3272	0644	edit dl rm
tree.tcl	3178	0644	edit dl rm
ttkbut.tcl	3405	0644	edit dl rm
ttkmenu.tcl	2391	0644	edit dl rm
ttknote.tcl	2317	0644	edit dl rm
ttkpane.tcl	4177	0644	edit dl rm
ttkprogress.tcl	1536	0644	edit dl rm
ttkscale.tcl	1420	0644	edit dl rm
twind.tcl	11654	0644	edit dl rm
unicodeout.tcl	4706	0644	edit dl rm
vscale.tcl	1477	0644	edit dl rm
widget	24064	0755	edit dl rm

Edit: /opt/imh/python3.13/lib/tk8.6/demos/search.tcl (4403B)

# search.tcl --
#
# This demonstration script creates a collection of widgets that
# allow you to load a file into a text widget, then perform searches
# on that file.

if {![info exists widgetDemo]} {
    error "This script should be run from the \"widget\" demo."
}

package require Tk

# textLoadFile --
# This procedure below loads a file into a text widget, discarding
# the previous contents of the widget. Tags for the old widget are
# not affected, however.
#
# Arguments:
# w -		The window into which to load the file.  Must be a
#		text widget.
# file -	The name of the file to load.  Must be readable.

proc textLoadFile {w file} {
    set f [open $file]
    $w delete 1.0 end
    while {![eof $f]} {
	$w insert end [read $f 10000]
    }
    close $f
}

# textSearch --
# Search for all instances of a given string in a text widget and
# apply a given tag to each instance found.
#
# Arguments:
# w -		The window in which to search.  Must be a text widget.
# string -	The string to search for.  The search is done using
#		exact matching only;  no special characters.
# tag -		Tag to apply to each instance of a matching string.

proc textSearch {w string tag} {
    $w tag remove search 0.0 end
    if {$string == ""} {
	return
    }
    set cur 1.0
    while 1 {
	set cur [$w search -count length $string $cur end]
	if {$cur == ""} {
	    break
	}
	$w tag add $tag $cur "$cur + $length char"
	set cur [$w index "$cur + $length char"]
    }
}

# textToggle --
# This procedure is invoked repeatedly to invoke two commands at
# periodic intervals.  It normally reschedules itself after each
# execution but if an error occurs (e.g. because the window was
# deleted) then it doesn't reschedule itself.
#
# Arguments:
# cmd1 -	Command to execute when procedure is called.
# sleep1 -	Ms to sleep after executing cmd1 before executing cmd2.
# cmd2 -	Command to execute in the *next* invocation of this
#		procedure.
# sleep2 -	Ms to sleep after executing cmd2 before executing cmd1 again.

proc textToggle {cmd1 sleep1 cmd2 sleep2} {
    catch {
	eval $cmd1
	after $sleep1 [list textToggle $cmd2 $sleep2 $cmd1 $sleep1]
    }
}

set w .search
catch {destroy $w}
toplevel $w
wm title $w "Text Demonstration - Search and Highlight"
wm iconname $w "search"
positionWindow $w

## See Code / Dismiss buttons
set btns [addSeeDismiss $w.buttons $w]
pack $btns -side bottom -fill x

frame $w.file
label $w.file.label -text "File name:" -width 13 -anchor w
entry $w.file.entry -width 40 -textvariable fileName
button $w.file.button -text "Load File" \
	-command "textLoadFile $w.text \$fileName"
pack $w.file.label $w.file.entry -side left
pack $w.file.button -side left -pady 5 -padx 10
bind $w.file.entry <Return> "
    textLoadFile $w.text \$fileName
    focus $w.string.entry
"
focus $w.file.entry

frame $w.string
label $w.string.label -text "Search string:" -width 13 -anchor w
entry $w.string.entry -width 40 -textvariable searchString
button $w.string.button -text "Highlight" \
	-command "textSearch $w.text \$searchString search"
pack $w.string.label $w.string.entry -side left
pack $w.string.button -side left -pady 5 -padx 10
bind $w.string.entry <Return> "textSearch $w.text \$searchString search"

text $w.text -yscrollcommand "$w.scroll set" -setgrid true
ttk::scrollbar $w.scroll -command "$w.text yview"
pack $w.file $w.string -side top -fill x
pack $w.scroll -side right -fill y
pack $w.text -expand yes -fill both

# Set up display styles for text highlighting.

if {[winfo depth $w] > 1} {
    textToggle "$w.text tag configure search -background \
	    #ce5555 -foreground white" 800 "$w.text tag configure \
	    search -background {} -foreground {}" 200
} else {
    textToggle "$w.text tag configure search -background \
	    black -foreground white" 800 "$w.text tag configure \
	    search -background {} -foreground {}" 200
}
$w.text insert 1.0 \
{This window demonstrates how to use the tagging facilities in text
widgets to implement a searching mechanism.  First, type a file name
in the top entry, then type <Return> or click on "Load File".  Then
type a string in the lower entry and type <Return> or click on
"Load File".  This will cause all of the instances of the string to
be tagged with the tag "search", and it will arrange for the tag's
display attributes to change to make all of the strings blink.}
$w.text mark set insert 0.0

set fileName ""
set searchString ""

cmd: